{ 23. velke mocniny matice }

const
  maxn = 50;
type
  tmatice = array[1..maxn, 1..maxn] of integer;

procedure vynasob(n : integer; var c : tmatice; a, b:tmatice); { "c:=a*b" }
{ !! pozor, u a, b nesmi byt var }
var
  i, j, k : integer;
begin
  for i:=1 to n do
   for j:=1 to n do
   begin
     c[i, j]:=0;
     for k:=1 to n do c[i, j]:=c[i, j]+ a[i, k] * b[k, j];
   end;
end;

{ mocni pomoci rozepsani exponentu do dvojkove soustavy }
procedure mocni(n : integer; var kam : tmatice; co : tmatice; kolik : integer);
var
  i, j : integer;
  pom : tmatice;
begin
  for i:=1 to n do
    for j:=1 to n do
     if (i = j) then kam[i, j]:=1 else kam[i, j]:=0;

  i:=0;
  pom:=co;

  while (kolik>0) do
  begin
     { pom = co ^ (2 ^ i) }
     if (kolik mod 2 = 1) then vynasob(n, kam, kam, pom);

     kolik:=kolik div 2;
     i:=i+1;
     vynasob(n, pom, pom, pom); { "pom:=pom*pom" }
  end;
end;

var
  i, j, n, p : integer;
  a, vysl : tmatice;
  f: text;
  ch: char;

begin
 { write('Zadej velikost matice (n): '); readln(n);
  write('Zadej pozadovanou mocninu: '); readln(p);
  write('Zadej matici:');
  for i:=1 to n do
   for j:=1 to n do read(a[i, j]);}

  write('Zadej velikost matice (n): '); readln(n);

  assign (f,'.\tmatice.txt');
  reset(f);
  for i:=1 to n do
   begin for j:=1 to n do read(f, a[i,j]);
   readln (f);
   end;


  write('Zadej pozadovanou mocninu: '); readln(p);
  mocni(n, vysl, a, p);

  writeln('Vysledek:');
  for i:=1 to n do
  begin
    for j:=1 to n do write (vysl[i, j]:8);
    writeln;
  end;
  close (f);
  read (ch);

end.

