{ 24. spocitej faktorial - napr. 250! - presne }

const
  max = 10000;
type
  tcislo = array[0..max] of integer;

{ nasobeni dlouheho cisla integerem }
function vynasob(var co : tcislo; cim : integer) : boolean;
 { vraci, zda to preteklo }
var
  i, s : integer;
begin
  s:=0;
  for i:=0 to max do
  begin
    s:=s + co[i] * cim; { nasobim po cifrach, podobne jako scitani }
     { pricetlo se s, tj. o kolik to preteklo v predchozim kroku }

    co[i]:=s mod 10;
    s:=s div 10; { spocitej, jak to preteklo }
  end;
  vynasob:=(s <> 0); { je-li to <>0, potom to preteklo - neveslo se do pole }
end;

var
  i, n, m : integer;
  fac : tcislo;
  chyba : boolean;
begin
  { "fac:=1" }
  for i:=0 to max do fac[i]:=0;
  fac[0]:=1;

  read(n); { vstup }

  chyba:=false;
  for i:=2 to n do { vynasob cisly 2, 3, .., N, tj. vypocet faktorialu }
  begin
    if vynasob(fac, i) then chyba:=true; { doslo-li k preteceni - zapamatuj }
  end;
  if chyba then writeln('Doslo k preteceni') else
  begin
    m:=0;
    for i:=0 to max do
     if fac[i] <> 0 then m:=i;
    write(n, '! = ');
    for i:=m downto 0 do write(fac[i]);
    writeln;
  end;
end.
