program slova;

Type
   ZAZNAM = record
               V : String;
               C : Integer;
            end;

Const
   N = 1000;	{ maximalni pocet slov }

var
   w 		: String;			 { pomocne slovo }
   S 		: array [1..N] of ZAZNAM;	 { pole zaznamu slov}


   i,j     	: Integer;	{ indexy pro pohyb v poli S }
   Vrchol	: Integer;	{ ukazatel na prvni volne policko v poli S}
   Prvni	: Integer;	{ zobrazime Prvni nejcastejsi slova }
   f		: Text;         { vstupni soubor }
   zn           : Char;    	{ pouze aby se mohl precist vypis a chyby }

procedure CtiSlovo;
{ procedura cte slovo do promenne w }
var
   ch         : Char;
   KonecSlova : Boolean;
begin
   { inicializace promennych }
   ch:=#0;
   w:='';
   KonecSlova:=FALSE;

   while ((not eoln(f)) and (not KonecSlova)) do begin
      read(f,ch);
      if (ch in ['A'..'Z']) then ch:=Chr(Ord(ch)-Ord('A')+Ord('a'));
      if (ch = ' ') then KonecSlova:=TRUE else w:=w+ch;
   end;
   if (eoln(f)) then readln(f,ch);
end;
{ ------------------------------------------------- }
procedure quicksort (l,r : integer);
var i,j,xh : integer;
    wh : ZAZNAM;
begin
 i:=l; j:=r;
 xh:=S[(l+r) div 2].C;
 repeat
   while S[i].C < xh do i:=i+1;
   while xh < S[j].C do j:=j-1;
   if i <= j then begin
     wh:=S[i];
     S[i]:= S[j];
     S[j]:=wh;
     i:=i+1;
     j:=j-1
   end
 until i > j;
 if l < j then quicksort(l,j);
 if i < r then quicksort(i,r)
end;



{ ================================================= }
begin

   { inicializace pole }
   for i:=1 to N do
      with S[i] do begin
            V:='';
            C:=0;
         end;
   Vrchol:=1;		{ pristi volne policko v poli }
   Assign(f,'.\data.txt');
   Reset(f);
   readln(f,Prvni);

   { cteni vstupnich dat }
   while (not eof(f)) do begin
      CtiSlovo;
      if (w <> '') then begin
         { hledame, zda jiz je v poli }
         i:=0;
         repeat
            i:=i+1
         until ((i=Vrchol) or (S[i].V=w));
         with S[i] do
            if (i=Vrchol) then begin
               V:=w;
               C:=1;
               Vrchol:=Vrchol+1;	{ novy vrchol }
            end
            else C:=C+1;		{ pouze zvysime citac }
      end;      { neprazdne slovo }
   end;         { konec souboru }

   Close(f);

   { setridit S podle C }
   quicksort(1,Vrchol-1);

   writeln('Prvnich ',Prvni,' nejcastejsich slov v danem souboru je:');
   writeln;

   j:=Vrchol-1;
   i:=Prvni;
   while ((i>0) and (j>0)) do begin
      with S[j] do writeln(V:8,'  ',C:5);
      i:=i-1;
      j:=j-1;
   end;

   read(zn);

end. { konec programu }
