program OVA;                   
const
  spaces:set of char = [' ',#13,#10,#9]; { mezerove znaky - ne konec souboru }
  char_eof: char = #26;                  { znak konce souboru }
  POCET = 3;                             { pocet slov pro test dopredu }

type
  wordItem = record
    word:       string;  { slovo }
    spaceAfter: string;  { mezera za slovem }
  end;

var
  readChar_next:char;                  { znak, ktery bude precte priste }
  readChar_first:boolean;              { priznak prvniho volani funkce readChar }
  words: array[1..POCET+1] of wordItem;{ fronta slov ze vstupu }
  i: integer;
  t1, t2: text;

function readNextChar:char;  { nacte dalsi znak }
  begin
    if readChar_first then
      begin
        read(t1,readChar_next); { preskoc na zacatku hned na prvni znak }
        readChar_first:=false;
      end;
    readNextChar:=readChar_next;
    read(t1,readChar_next);
  end;

function getNextChar:char; { vrati jaky bude nacten dalsi znak }
  begin
    if readChar_first then begin
      read(t1,readChar_next); { preskoc na zacatku hned na prvni znak }
      readChar_first:=false;
    end;
    getNextChar:=readChar_next;
  end;

function readNextSpace:string; { precte dalsi mezeru mezi slovy ze vstupu }
  var  s:string;
  begin
    s:='';
    while (getNextChar<>char_eof) and (getNextChar in spaces) do  s:=s+readNextChar;
    readNextSpace:=s;
  end;

function readNextWord:string; { precte dalsi slovo ze vstupu }
  var s:string;
  begin
    s:='';
    while (getNextChar<>char_eof) and ( not (getNextChar in spaces)) do s:=s+readNextChar;
    readNextWord:=s;
  end;

function maskedWord(s:string):string; { vraci string obsahujici stejne * jako delka puvodniho slova }
  var i:integer; so:string;
  begin
    so:='';
    for i:=1 to length(s) do so:=so+'*';
    maskedWord:=so;
  end;

function isToMask(s:string):boolean; { vraci true, pokud slovo konci na [Oo][Vv][Aa] }
  begin
    if length(s)>=3
      then
        if ((s[length(s)-2]='o') or (s[length(s)-2]='O')) and ((s[length(s)-1]='v') or (s[length(s)-1]='V')) and
           ((s[length(s)]='a') or (s[length(s)]='A'))
          then isToMask:=true
          else isToMask:=false
      else isToMask:=false;
  end;

function wordsStep:boolean; { posune se ve cteni o slovo a nasledujici mezeru a vrati priznak konce vstupu }
  var i:integer;  mask:boolean;  empty:boolean;
  begin
    empty:=words[1].word='';
    mask:=false;
    for i:=2 to POCET+1 do      { test na skryti }
      if isToMask(words[i].word) then  mask:=true;
    if mask   { zamaskovani slova nebo prosty vypis }
      then write(t2,maskedWord(words[1].word))
      else write(t2,words[1].word);

    write(t2,words[1].spaceAfter);   { vypis mezery za slovem }
    for i:=1 to POCET do words[i]:=words[i+1]; { rotace slov }
    words[POCET+1].word:=readNextWord;  { nacteni dalsiho slova a mezery za nim }
    words[POCET+1].spaceAfter:=readNextSpace;
    wordsStep:=not empty;
  end;

begin
  readChar_next:=' ';
  readChar_first:=true;
  assign(t1,'vstupK39.txt'); reset(t1);
  assign(t2,'K39.txt');      rewrite(t2);

  write(t2,readNextSpace); { nacteni vypsani pripadne pocatecni mezery }

  for i:=1 to POCET+1 do wordsStep;   { naplneni vstupni fronty }

  while true do if not wordsStep then break;   { zbytek souboru }

  close(t1);  close(t2);
end.
